1 REM 64 VERSION/WALLACE
100 PRINT"[147]":GOTO230
105 POKE198,0:PRINT"[145]";J$;" NOT ON FILE":GOSUB130:RETURN
110 IFE$="NONE"THENRETURN
115 E$=RIGHT$(E$,5)+" "+LEFT$(E$,2)+" ":RETURN
120 PRINT"SEARCHING[146]":RETURN
125 PRINT"PRESS C TO CONTINUE"
130 PRINT"PRESS M FOR MENU"
135 GETF$:IFF$=""THEN135
140 RETURN
145 PRINT"[147]ENTER MONTH EXPIRES (2 DIGITS)":FORL=1TO6:E$(L)="":NEXT
150 IFZ1=0THENPRINT"ENTER N IF NO EXPIRATION"
155 FORL=1TO6
160 GETE$(L):IFE$(L)=""ORE$(L)<"0"ORE$(L)>"9"ANDE$(L)<>"N"THEN160
165 IFZ1=1ANDE$(L)="N"THEN160
170 IFE$(L)="N"ANDZ1=0THEN205
175 PRINT""E$(L)"[145]"
180 IFL=2THENPRINT""E$(1);E$(2):PRINT"ENTER DAY (2 DIGITS)
185 [139]L[178]4[167][153]""E$(3);E$(4):[153]"ENTER YEAR (2 DIGITS)
190 NEXT:PRINT""E$(5);E$(6)
195 E$=E$(5)+E$(6)+" "+E$(1)+E$(2)+" "+E$(3)+E$(4)
200 E1$=E$(1)+E$(2)+" "+E$(3)+E$(4)+" "+E$(5)+E$(6):GOTO210
205 E$="NONE":E1$=E$
210 PRINT""E1$:PRINT"OK (Y/N)"
215 GOSUB135:IFF$="N"THEN145
220 IFF$="Y"THENRETURN
225 GOTO215
230 BC=53280:SC=53281:POKEBC,6:POKESC,1:B%=0:C%=0:D1$=" CENTS "
235 PRINT"[147][151]COUPON ORGANIZER[146]":PRINT"1[146]  REVIEW ENTIRE FILE"
240 PRINT" 2[146]  SEARCH BY BRAND NAME":PRINT" 3[146]  SEARCH BY PRODUCT"
245 PRINT" 4[146]  COMPUTE TOTAL VALUE":PRINT" 5[146]  DUMP TO PRINTER"
250 PRINT" 6[146]  UPDATE COUPON FILE":PRINT" 7[146]  SAVE UPDATED FILE"
255 PRINT" 8[146]  QUIT":PRINT"SELECT FUNCTION[146]"
260 GOSUB135:RESTORE:IFF$<"1"ORF$>"8"THEN260
265 A=VAL(F$):ONAGOTO275,290,295,555,335,610,590,270:GOTO265
270 SC=53281:POKESC,6:POKEBC,14:PRINT"[147][154]":CLR:END
275 POKEBC,7:GOSUB540:IFA$="END"THEN230
280 PRINT"[147]":GOSUB445:IFF$="M"THEN230
285 GOTO275
290 POKEBC,8:INPUT"[147]   ENTER BRAND";J$:GOSUB120:B%=1:GOTO300
295 POKEBC,9:INPUT"[147]   ENTER PRODUCT";J$:GOSUB120:C%=1
300 GOSUB540:IFA$="END"THEN325
305 IFB%THENIFB$<>J$THEN300
310 IFC%THENIFC$<>J$THEN300
315 GOSUB445:GOSUB120:Z=1:IFF$="M"THEN230
320 GOTO300
325 IFZTHEN230
330 GOSUB105:GOTO230
335 POKEBC,15:PRINT"[147]PRINTER READY? (Y/N)"
340 GOSUB135:IFF$<>"Y"ANDF$<>"N"THEN340
345 IFF$="N"THEN230
350 OPEN1,4,1
355 READA$:IFA$="END"THENCLOSE1:GOTO230
360 IFA$="#"THENREADA:GOTO355
365 READB$,C$,D$,E$:GOSUB110
370 PRINT#1,A$" "C$"    "B$"  "D$D1$"  "E$:IFPTHENCLOSE1:GOTO425
375 GOTO355
380 Z=0:RESTORE:Z1=1:GOSUB145:Z1=0:J$=E$
385 PRINT"[147]":GOSUB120:D1$=" CENTS "
390 GOSUB540:IFA$="END"THEN430
395 IFVAL(E$)>VAL(J$)ORVAL(E$)<1THEN390
400 P=1:GOSUB445:GOSUB120:Z=1:IFF$="M"THEN230
405 IFF$="P"THENR$=A$:PRINT"[145]HARD COPY? (Y/N)":GOTO415
410 GOTO390
415 GOSUB135:IFF$="Y"THENOPEN1,4,1:GOTO370
420 IFF$<>"N"THEN415
425 GOTO690
430 IFZTHEN440
435 E$=J$:GOSUB115:PRINT"[145]   NONE EXPIRED AS OF ";E$;"":GOSUB130
440 P=0:GOTO230
445 FORL=1TO3:D(L)=INT(RND(0)*14)+2:NEXT:B=32:E=646
450 H$="                                    [146]":PRINT"[147]   FILE NUMBER:";A$
455 POKEE,D(1):PRINT"";H$:PRINT;H$:PRINT;H$
460 FORL=1TO7:PRINT"          ":POKEE,D(2):PRINT,"[145][157]                      "
465 POKEE,D(1):PRINT,,,"[145]      ":NEXT:PRINT;H$:PRINT;H$
470 PRINT" [175] [175] [175] [175][160][175] [175] [175] [175] [175][160][175] [175][160][175] [175][160][175] [175] [175] [146]"
475 FORL=1TO5:PRINT"[170]"SPC(31)"[180]":PRINT:NEXT
480 PRINT" [183] [183] [183] [183] [183] [183] [183] [183] [183] [183] [183] [183] [183] [183] [183] [183] [146]":GOSUB110
485 IFVAL(D$)>99THENB=29:IFVAL(D$)>999THENB=28
490 IFVAL(D$)>99THEND$="$"+LEFT$(D$,LEN(D$)-2)+"."+RIGHT$(D$,2)
495 IFD$="FREE"THENB=30
500 POKEE,D(3):PRINT""TAB(5)D$TAB(B)D$:POKEE,D(2):PRINT,""B$
505 PRINT,""C$:PRINT,"EXP. DATE: "E$:POKEE,D(3):PRINT""TAB(5)D$TAB(B)D$
510 PRINT"[146][151]":POKE198,0
515 IFPTHENPRINT"PRESS P TO PURGE COUPON[146]"
520 GOSUB125:IFF$<>"M"ANDF$<>"C"ANDF$<>"P"THENPRINT"[145][145][145][145][145]":GOTO530
525 RETURN
530 IFPTHENPRINT"[145]"
535 GOTO520
540 READA$:IFA$="END"THENRETURN
545 IFA$="#"THENREADA:GOTO540
550 READB$,C$,D$,E$:RETURN
555 D$="":T=0
560 POKEBC,5:GOSUB540:IFA$="END"THEN570
565 T=T+VAL(D$):PRINT"[147]";T:POKEBC,13:GOTO560
570 T$=STR$(T):Z$=RIGHT$(T$,2):X$=LEFT$(T$,LEN(T$)-2):T$=X$+"."+Z$
575 PRINT"[147]TOTAL VALUE: $";T$;""
580 GOSUB130:IFF$<>"M"THENPRINT"[145][145][145]":GOTO580
585 GOTO230
590 POKEBC,4:PRINT"[147]T[146]APE OR D[146]ISK?[145]":GOSUB135:IFF$<>"T"ANDF$<>"D"THEN590
595 IFF$="T"THENSAVE"COUPON ORGANIZER":GOTO230
600 PRINT"SAVING UPDATE[146]":OPEN15,8,15:PRINT#15,"S0:COUPON ORGANIZER"
605 CLOSE15:SAVE"COUPON ORGANIZER",8:GOTO230
610 BC=53280:POKEBC,2:PRINT"[147] 1[146]  ADD NEW COUPONS"
615 PRINT" 2[146]  PURGE REDEEMED COUPONS"
620 PRINT" 3[146]  PURGE EXPIRED COUPONS":PRINT" 4[146]  RETURN TO MENU"
625 P$(1)="BRAND NAME":P$(2)="PRODUCT":P$(3)="COUPON VALUE (IN CENTS)"
630 D1$=" CENTS "
635 GOSUB135:A=VAL(F$):ONAGOTO645,685,380,230:GOTO610
640 POKE198,2:POKE631,13:POKE632,13:END
645 PRINT" STANDBY[146]"
650 A=VAL(A$)+1:READA$:IFA$="#"THENREADA:GOTO660
655 IFA$<>"END"THENREADB$,C$,D$,E$:GOTO650
660 PRINT"[147]ITEM : "A"":FORI=1TO3:PRINT""P$(I):INPUT"";W$(I)
665 IFW$(1)=""THEN610
670 NEXT:GOSUB145:W$(0)=STR$(A):M=A*5+1000:PRINT"[147]"
675 PRINTM;"DATA"A","W$(1)","W$(2)","W$(3)","E$
680 PRINT"GOTO610":GOTO640
685 PRINT"[147]REMOVE FILE NUMBER":INPUT"   ";R$:IFVAL(R$)=0THEN685
690 PRINT"[147]":M=VAL(R$)*5+1000:PRINTM"DATA"CHR$(34)"#"CHR$(34)","VAL(R$)
695 IFPTHENP=0:GOTO705
700 PRINT"J$="CHR$(34)J$CHR$(34)":Z=1:GOTO610":GOTO640
705 PRINT"J$="CHR$(34)J$CHR$(34)":Z=1:GOTO385":GOTO640
1000 REM FILES
1005 DATA 1 ,SAMPLE COUPON,EXAMPLE ONLY,NONE,NONE
50000 DATAEND